Home

Logithèque

TI83

Tracé du flocon de Koch

Code

5->N:{N,11}->dim([I])
Xmin->[I](1,4)
Ans->[I](1,10)
(2Ymax+Ymin)/3->[I](1,5)
Ans->[I](1,7)
Ans->[I](1,11)
Xmax->[I](1,6)
(Xmin+Xmax)/2->[I](1,8)
Ymin->[I](1,9)
1->L:4->J

Lbl PU
[I](L,J)->P:[I](L,J+1)->Q:[I](L,J+2)->R:[I](L,J+3)->S
J->[I](L,1)
L+1->L:2->J

P->[I](L,2)
Q->[I](L,3)
R->[I](L,10)
S->[I](L,11)
(2P+R)/3->[I](L,4)
(2Q+S)/3->[I](L,5)
(2R+P)/3->[I](L,8)
(2S+Q)/3->[I](L,9)
((1+iSQRT(3^-1))*((R-P)+i*(S-Q)))/2->R
P+real(R)->[I](L,6)
Q+imag(R)->[I](L,7)

Lbl B
If L<N:Goto PU
For(I,2,8,2)
Line([I](L,I),[I](L,I+1),[I](L,I+2),[I](L,I+3)):End:J+2->J

Lbl PO
L-1->L
If L<=0:Stop
[I](L,1)+2->J
If J<9:Goto B
Goto PO

Attention en 25ème ligne la lettre "i" est l'unité imaginaire, SQRT représente la fonction racine carrée, et "^-1" représente la fonction inverse.

Mode d'emploi

Si l'on veut une profondeur différente de 5, remplacer la valeur figurant au tout début du programme.

Lancer le programme. Le flocon de Koch s'affiche. C'est tout !!!!!

Pour mémoire le flocon de Koch est la limite d'une suite de figures commençant par un triangle équilatéral. Pour passer d'une figure de la suite à sa suivante, on divise tous ses segments en trois parties et on remplace celle du centre par deux côtés de triangle équilatéral dont la base aurait été le segment retiré.

On peut choisir d'orienter le triangle "vers l'extérieur" ou "vers l'intérieur", ici nous traçons le premier cas.